1. Mục tiêu bài học
Bài 4 nhằm giúp người học chuyển từ mô tả dữ liệu sang phân tích mô hình các nhân tố có liên quan đến đổi mới của doanh nghiệp. Sau bài học, người học có thể ước lượng và diễn giải mô hình Binary Logit cho biến đổi mới nhị phân; phân biệt hệ số Logit, odds ratio, xác suất dự báo và hiệu ứng biên trung bình; sử dụng margins và marginsplot để so sánh xác suất dự báo giữa các nhóm doanh nghiệp; ước lượng riêng cho SMEs và so sánh với toàn bộ mẫu; phân tích riêng đổi mới sản phẩm và đổi mới quy trình; ước lượng Multinomial Logit cho các trạng thái đổi mới; đồng thời mở rộng mô hình với các yếu tố cơ sở hạ tầng, kiểm tra đa cộng tuyến và thực hiện các kiểm tra độ nhạy. Lưu ý: Các biến được sử dụng chỉ mang tính tham khảo. Nếu thực hiện nghiên cứu như thế này, bạn phải lược khảo cơ sở lý thuyết, đặc biệt là các nghiên cứu thực nghiệm để xác định các biến giải thích phù hợp.
2. Dữ liệu và chuỗi xử lý
Bài 4 sử dụng đầu ra của Bài 3 và tạo một tệp mới ở cuối bài:
wbes2023.dta → wbes2023_renamed.dta → wbes2023_clean.dta →
wbes2023_analysis.dta → wbes2023_innovation.dta
Biến phụ thuộc chính là any_innov. Các biến kết quả bổ sung gồm product_innov_d, process_innov_d và innov_type. Quy mô phân tích firm_size được xây dựng từ số lao động toàn thời gian hiện tại ở Bài 3.
3. Một số khái niệm cần nhớ trước khi chạy mô hình
Cần tham khảo các giáo trình Kinh tế lượng, ví dụ như Gujarati (2011): Chapters 8 & 9.
4. Thiết lập dữ liệu
clear all
set more off
cd “D:\Stata\WBES2023”
use “wbes2023_analysis.dta”, clear
clear all xóa dữ liệu và đối tượng đang có trong bộ nhớ; set more off tránh Stata dừng màn hình; cd đặt thư mục làm việc; use mở tệp wbes2023_analysis.dta do Bài 3 tạo ra.
5. Kiểm tra dữ liệu đầu vào
describe, short
count
isid id
describe any_innov innov_type product_innov_d process_innov_d ///
firm_size firm_age ln_emp manager_exp foreign_owned state_owned ///
exporter foreign_input female_manager_d formal_training_d ///
foreign_tech_d quality_cert_d website_d credit_line_d ///
power_outage_d internet_disrupt_d
tab any_innov, missing
tab innov_type, missing
tab firm_size, missing
Kiểm tra cấu trúc dữ liệu, số quan sát, tính duy nhất của id và sự tồn tại của các biến cần dùng. Đây là bước bảo đảm Bài 4 đang đọc đúng tệp đầu ra của Bài 3 trước khi ước lượng.
6. Xác định nhóm SMEs
generate byte sme = .
replace sme = 1 if inlist(firm_size, 1, 2)
replace sme = 0 if firm_size == 3
label define sme_lbl 0 “Doanh nghiệp lớn” 1 “SMEs”
label values sme sme_lbl
label variable sme “Doanh nghiệp nhỏ và vừa (SMEs)”
tab sme, missing
tab firm_size sme, missing
Tạo biến sme để tách SMEs khỏi doanh nghiệp lớn. Trong bài thực hành, SMEs gồm firm_size = 1 hoặc 2, tương ứng 5–99 lao động; đây là phân nhóm phân tích, không phải định nghĩa pháp lý SMEs của Việt Nam.
7. Khám phá các biến phụ thuộc về đổi mới
tab any_innov, missing
tab product_innov_d, missing
tab process_innov_d, missing
tab innov_type, missing
tab innov_type sme, column nofreq
Khám phá phân phối của các biến kết quả trước khi chạy mô hình. Bảng innov_type theo sme giúp xem cơ cấu bốn trạng thái đổi mới có khác nhau sơ bộ giữa SMEs và doanh nghiệp lớn hay không.
8. Khám phá các biến giải thích
Khám phá các biến giải thích theo bốn nhóm: đặc điểm doanh nghiệp; hội nhập thị trường, nguồn lực và công nghệ; cơ sở hạ tầng; và các bảng hai chiều với trạng thái đổi mới. Các bảng row percentages chỉ mang tính mô tả.
8.1. Đặc điểm doanh nghiệp
summarize firm_age ln_emp manager_exp, detail
tab firm_size, missing
tab foreign_owned, missing
tab state_owned, missing
tab female_manager_d, missing
Xem phân phối tuổi doanh nghiệp, log lao động, kinh nghiệm quản lý, quy mô, sở hữu và giới của quản lý cấp cao. Lệnh summarize, detail đặc biệt hữu ích để nhận biết độ phân tán và các giá trị cực trị.
8.2. Hội nhập thị trường, nguồn lực và công nghệ
tab exporter, missing
tab foreign_input, missing
tab formal_training_d, missing
tab foreign_tech_d, missing
tab quality_cert_d, missing
tab website_d, missing
tab credit_line_d, missing
Mô tả các yếu tố liên quan đến thị trường, nguồn lực, công nghệ và tài chính. Với các biến dummy, tab cho biết số doanh nghiệp ở trạng thái 0/1.
8.3. Cơ sở hạ tầng
tab power_outage_d, missing
tab internet_disrupt_d, missing
Mô tả hai điều kiện cơ sở hạ tầng được dùng ở mô hình mở rộng: mất điện và gián đoạn Internet.
8.4. So sánh sơ bộ theo trạng thái đổi mới
tab firm_size any_innov, row nofreq
tab foreign_owned any_innov, row nofreq
tab exporter any_innov, row nofreq
tab female_manager_d any_innov, row nofreq
tab formal_training_d any_innov, row nofreq
tab foreign_tech_d any_innov, row nofreq
tab quality_cert_d any_innov, row nofreq
tab website_d any_innov, row nofreq
tab credit_line_d any_innov, row nofreq
So sánh tỷ lệ đổi mới theo từng đặc điểm doanh nghiệp. Đây là so sánh thô, chưa kiểm soát đồng thời các yếu tố khác.
9. Kiểm tra missing trước khi ước lượng
misstable summarize any_innov innov_type firm_size firm_age ln_emp ///
manager_exp foreign_owned state_owned exporter foreign_input ///
female_manager_d formal_training_d foreign_tech_d quality_cert_d ///
website_d credit_line_d power_outage_d internet_disrupt_d
count if !missing(any_innov, firm_size, firm_age, ln_emp, manager_exp, ///
foreign_owned, exporter, female_manager_d, formal_training_d)
count if sme == 1 & !missing(any_innov, firm_size, firm_age, ln_emp, ///
manager_exp, foreign_owned, exporter, female_manager_d, formal_training_d)
Kiểm tra missing trước ước lượng để hiểu vì sao số quan sát của mô hình có thể thấp hơn tổng số doanh nghiệp. Hai lệnh count cho biết số quan sát hoàn chỉnh cho toàn mẫu và cho SMEs đối với một tập biến cốt lõi.
10. Binary Logit cho toàn bộ doanh nghiệp
Ước lượng Binary Logit cơ sở cho any_innov. Mô hình đưa vào quy mô, tuổi, log lao động, sở hữu nước ngoài và giới của quản lý. estimates store lưu kết quả để dùng lại ở các bước so sánh.
10.1. Mô hình cơ sở
logit any_innov i.firm_size c.firm_age c.ln_emp ///
i.foreign_owned i.female_manager_d
estimates store logit_all_m1
logit báo hệ số trên thang log-odds. Dấu dương cho thấy biến có liên hệ dương với log-odds đổi mới, nhưng không nên đọc trực tiếp hệ số như mức thay đổi của xác suất.
Các hệ số ước lượng đều không có ý nghĩa thống kê ở mức alpha = 5%.
10.2. Odds ratios
logistic any_innov i.firm_size c.firm_age c.ln_emp ///
i.foreign_owned i.female_manager_d
logistic ước lượng cùng mô hình nhưng hiển thị odds ratio. OR > 1 gắn với odds đổi mới cao hơn; OR < 1 gắn với odds thấp hơn, giữ các biến khác không đổi.
Cách khác:
logit any_innov i.firm_size c.firm_age c.ln_emp ///
i.foreign_owned i.female_manager_d, or
10.3. Xác suất dự báo theo quy mô doanh nghiệp
estimates restore logit_all_m1
margins firm_size
marginsplot, ///
title(“Xác suất đổi mới theo quy mô doanh nghiệp”) ///
ytitle(“Xác suất dự báo”) ///
xtitle(“Quy mô doanh nghiệp”) ///
ylabel(0(.1)1)
marginsplot, ///
title(“Xác suất đổi mới theo quy mô doanh nghiệp”) ///
ytitle(“Xác suất dự báo”) ///
xtitle(“Quy mô doanh nghiệp”) ///
ylabel(.05(.05).25)
margins firm_size tính xác suất đổi mới dự báo cho từng nhóm quy mô. Hai marginsplot dùng cùng kết quả nhưng thang trục tung khác nhau để minh họa cách lựa chọn scale ảnh hưởng đến cảm nhận trực quan, không làm thay đổi kết quả mô hình.
10.4. So sánh nhiều đường theo quy mô và giới của quản lý
margins firm_size#female_manager_d
marginsplot, ///
xdimension(firm_size) ///
plotdimension(female_manager_d) ///
title(“Xác suất đổi mới theo quy mô và giới của quản lý”) ///
ytitle(“Xác suất dự báo”) ///
xtitle(“Quy mô doanh nghiệp”) ///
ylabel(0(.1)1)
label define manager_gender_lbl 0 “Nam” 1 “Nữ”
label values female_manager_d manager_gender_lbl
marginsplot, ///
xdimension(firm_size) ///
plotdimension(female_manager_d) ///
title(“Xác suất đổi mới theo quy mô và giới của quản lý”) ///
ytitle(“Xác suất dự báo”) ///
xtitle(“Quy mô doanh nghiệp”) ///
ylabel(.05(.05).25)
11. Binary Logit mở rộng cho toàn bộ doanh nghiệp
logit any_innov i.firm_size c.firm_age c.ln_emp c.manager_exp ///
i.foreign_owned i.female_manager_d i.exporter i.foreign_input ///
i.formal_training_d i.foreign_tech_d i.quality_cert_d ///
i.website_d i.credit_line_d
estimates store logit_all_m2
Mở rộng mô hình Binary Logit bằng kinh nghiệm quản lý, xuất khẩu, đầu vào nước ngoài, đào tạo, công nghệ nước ngoài, chứng nhận chất lượng, website và hạn mức tín dụng.
set showbaselevels off
logit any_innov i.firm_size c.firm_age c.ln_emp c.manager_exp ///
i.foreign_owned i.female_manager_d i.exporter i.foreign_input ///
i.formal_training_d i.foreign_tech_d i.quality_cert_d ///
i.website_d i.credit_line_d
11.1. So sánh mô hình cơ sở và mô hình mở rộng
estimates table logit_all_m1 logit_all_m2, ///
b(%9.3f) se(%9.3f) stats(N ll)
So sánh hệ số, sai số chuẩn, số quan sát và log likelihood của mô hình cơ sở với mô hình mở rộng. Không nên chỉ dựa vào một hệ số riêng lẻ để kết luận mô hình nào tốt hơn.
11.2. Kiểm định và đánh giá mô hình
estimates restore logit_all_m2
testparm i.firm_size
estat gof, group(10)
estat classification
testparm kiểm định chung các nhóm của firm_size. estat gof cung cấp kiểm tra độ phù hợp theo nhóm; estat classification cho bảng phân loại dự báo. Các chỉ tiêu này bổ sung cho nhau.
Hãy chạy do-file và đánh giá mô hình m2!
11.3. Hiệu ứng biên trung bình
margins, dydx(*)
AME của mô hình mở rộng thường dễ truyền đạt hơn hệ số log-odds, nhất là khi mục tiêu là giải thích khác biệt xác suất đổi mới.
11.4. Xác suất đổi mới theo quy mô doanh nghiệp
margins firm_size
marginsplot, ///
title(“Xác suất đổi mới theo quy mô doanh nghiệp”) ///
subtitle(“Mô hình Binary Logit mở rộng”) ///
ytitle(“Xác suất dự báo”) ///
xtitle(“Quy mô doanh nghiệp”) ///
ylabel(0(.05).6)
marginsplot, ///
title(“Xác suất đổi mới theo quy mô doanh nghiệp”) ///
subtitle(“Mô hình Binary Logit mở rộng”) ///
ytitle(“Xác suất dự báo”) ///
xtitle(“Quy mô doanh nghiệp”) ///
ylabel(0(.05).6) ///
xlabel(, angle(30))
11.5. So sánh xác suất theo quy mô và đào tạo
margins firm_size#formal_training_d
marginsplot, ///
xdimension(firm_size) ///
plotdimension(formal_training_d) ///
title(“Xác suất đổi mới theo quy mô và đào tạo”) ///
ytitle(“Xác suất dự báo”) ///
xtitle(“Quy mô doanh nghiệp”) ///
ylabel(0(.05).6) xlabel(, angle(30))
11.6. So sánh xác suất theo quy mô và chứng nhận chất lượng
margins firm_size#quality_cert_d
marginsplot, ///
xdimension(firm_size) ///
plotdimension(quality_cert_d) ///
title(“Xác suất đổi mới theo quy mô và chứng nhận chất lượng”) ///
ytitle(“Xác suất dự báo”) ///
xtitle(“Quy mô doanh nghiệp”) ///
ylabel(0(.05).6) xlabel(, angle(30))
12. Binary Logit cho nhóm SMEs
set showbaselevels off
logit any_innov i.firm_size c.firm_age c.ln_emp c.manager_exp ///
i.foreign_owned i.female_manager_d i.exporter i.foreign_input ///
i.formal_training_d i.foreign_tech_d i.quality_cert_d ///
i.website_d i.credit_line_d if sme == 1
estimates store logit_sme
Ước lượng cùng mô hình mở rộng nhưng giới hạn mẫu ở sme == 1. Vì SMEs chỉ gồm doanh nghiệp nhỏ và vừa, firm_size trong mô hình này chỉ còn hai nhóm.
Hãy chạy do-file để xem kết quả ước lượng.
12.1. Hiệu ứng biên trung bình trong nhóm SMEs
margins, dydx(*)
AME được tính trong chính mẫu SMEs, vì vậy không nên mặc nhiên xem chúng giống AME của toàn bộ mẫu.
Hãy chạy do-file để xem kết quả ước lượng.
12.2. Xác suất đổi mới giữa doanh nghiệp nhỏ và vừa
margins firm_size
marginsplot, ///
title(“Xác suất đổi mới của SMEs theo quy mô”) ///
subtitle(“So sánh doanh nghiệp nhỏ và vừa”) ///
ytitle(“Xác suất dự báo”) ///
xtitle(“Quy mô doanh nghiệp”) ///
ylabel(0(.05).35) xlabel(, angle(30))
13. Đổi mới sản phẩm và đổi mới quy trình
logit product_innov_d i.firm_size c.firm_age c.ln_emp c.manager_exp ///
i.foreign_owned i.female_manager_d i.exporter i.foreign_input ///
i.formal_training_d i.foreign_tech_d i.quality_cert_d ///
i.website_d i.credit_line_d
estimates store logit_product
logit process_innov_d i.firm_size c.firm_age c.ln_emp c.manager_exp ///
i.foreign_owned i.female_manager_d i.exporter i.foreign_input ///
i.formal_training_d i.foreign_tech_d i.quality_cert_d ///
i.website_d i.credit_line_d
estimates store logit_process
estimates table logit_product logit_process, ///
b(%9.3f) se(%9.3f) stats(N ll)
14. Multinomial Logit cho loại hình đổi mới
tab innov_type, missing
mlogit innov_type i.firm_size c.firm_age c.ln_emp c.manager_exp ///
i.foreign_owned i.female_manager_d i.exporter i.foreign_input ///
i.formal_training_d i.foreign_tech_d i.quality_cert_d ///
i.website_d i.credit_line_d, baseoutcome(0)
estimates store mnl_all
MNL sử dụng innov_type gồm bốn trạng thái. Nhóm 0 = không đổi mới là base outcome. Trước khi ước lượng phải kiểm tra số quan sát của từng nhóm; nhóm quá nhỏ có thể làm ước lượng kém ổn định.
Hãy chạy do-file để xem kết quả ước lượng.
15. Multinomial Logit cho nhóm SMEs
tab innov_type if sme == 1, missing
mlogit innov_type i.firm_size c.firm_age c.ln_emp c.manager_exp ///
i.foreign_owned i.female_manager_d i.exporter i.foreign_input ///
i.formal_training_d i.foreign_tech_d i.quality_cert_d ///
i.website_d i.credit_line_d if sme == 1, baseoutcome(0)
estimates store mnl_sme
Lặp lại MNL cho SMEs. Cần xem tab innov_type if sme == 1 trước vì một số trạng thái đổi mới có thể có ít quan sát hơn khi thu hẹp mẫu.
Hãy chạy do-file để xem kết quả ước lượng, cũng như các kết quả khác (thêm biến cơ sở hạ tầng, kiểm tra đa cộng tuyến, …).